I noticed that my little password routine would repeatedly create the same password each time I used it anew, after re-starting the computer and re-launching Excel. It turns out that VBA’s RAND function is not as random as you’d think it might be. The way around this is

I saw this code that I found on the techguy forum:

  seed = TimeValue("00:" & Format(Second(Time), "00") & ":" & Format(Minute(Time), "00"))
  Randomize (seed)

But according to the RND entry at the support site, you can just call Randomize on its own:

Before calling Rnd, use the Randomize statement without an argument to initialize the random-number generator with a seed based on the system timer.

I had never used Randomize before, and never knew that I needed to. In Python, a more sophisticated programming language, seeding is taken care of for you: “current system time is also used to initialize the generator when the module is first imported.”

Lots more information at the Wikipedia article on Pseudo-Random Number Generators. From here I learned, “A PRNG can be started from an arbitrary starting state using a seed state. It will always produce the same sequence thereafter when initialized with that state.”

If a line in your function produces a run-time error, you won’t get a popup message like you would for a Subroutine. Instead, code execution ends immediately, and you get the error #VALUE! in the cell on the worksheet.

It is often useful to return a more descriptive error. To do this, you can use On Error to trap the error, and return one of Excel’s built in error types. To do this, use the VBA function CVErr and a constant to set the built-in error type. These are (via the online help under “Cell Error Values”):

Error number

Cell error value

2007

#DIV/0!

2042

#N/A

2029

#NAME?

2000

#NULL!

2036

#NUM!

2023

#REF!

2015

#VALUE!

For your UDF to return custom errors, you must declare the function so that it returns the data type Variant. See also this Microsoft knowldgebase article on Error Trapping with Visual Basic for Applications.

Here’s an example of a UDF that returns the error #N/A. In this case, the function is a slightly more sophisticated version of the built-in function FIND, which returns the starting position of a one text string within another string. I wanted a function that would return the nth position, rather than just the first occurrence.

Function FindNth(find_text As String, within_text As String, n As Long) As Variant

'Finding the nth occurrence of a text string within another text string

'Uses Excel's built-in Worksheet Find function iteratively

'(probably faster than a brute-force approach using a loop)

'If find_text is not found, returns the error #N/A

  Dim pos As Variant

  Dim i As Long

  Dim result As Long

  i = 0

  result = 0

  Do

    On Error GoTo ErrLine

    pos = Application.WorksheetFunction.Find(find_text, within_text)

    result = result + pos

    i = i + 1

    If i = n Then Exit Do

    within_text = Right(within_text, Len(within_text) - pos)

  Loop

  FindNth = result

  Exit Function

ErrLine: FindNth = CVErr(xlErrNA)

End Function

For example:

=FINDNTH(" ", "Mira Vista Avenue", 2)

Returns 11, the position of the second occurrence of a space in “Mira Vista Avenue”.

=FINDNTH("x", "Microsoft", 3)

Returns #N/A, since it is looking for the 3^rd letter x in “Microsoft”, and can’t find it.

In this example, the function should probably return #VALUE! to copy the FIND function’s built-in behavior. But I wanted to differentiate between a VBA run-time error and an error returned by the function, and #N/A seemed to fit the bill.

if substring in string:

  #Then do something…

But Excel lacks this convenience. You can sort of hack the built in InStr function to do it for you. Since I always found this confusing (who can remember what the difference is between “text compare” and “binary compare”?), I created a simple function called Contains. On the spreadsheet, you can just type

=Contains("abcdefg", "a"

) and it returns TRUE. In VBA, it is useful in IF statements. Not as clean as Python, but a helpful convenience.

Function Contains(str As String, substr As String, _

   Optional CaseSensitive As Boolean = False) As Boolean

'Does a simple test to see if str contains substr

'Example: =Contains("abcd","a") returns TRUE

'         =Contains("abcd","x") returns FALSE

'Set CaseSensitive flag to TRUE if you don't want "a" to find "A"

'         =Contains("ABCD","a",True) returns FALSE

'         =Contains("ABCD","a",False) returns TRUE (because the comparison is case sensitive)

Dim opt As Long

If CaseSensitive Then

  opt = vbBinaryCompare

Else

  opt = vbTextCompare

End If

If InStr(1, str, substr, opt) > 0 Then

  Contains = True

Else

  Contains = False

End If

End Function

The function LARGE returns the k^th largest value in a dataset. Entering

=LARGE(A1:A9,3) 

returns the third largest value in the range A1 to A9. The function is smart enough to ignore blank cells and text. However, if you have an error in a cells, the result of the formula will be an error.

Here are custom functions to replace the built-in ones, called MyLarge and MySmall. Their use is identical to the Excel version: just enter

=MYLARGE(A1:A9,3).

If you don’t know how to use these, check out the following: How do I… Create a user-defined function in Microsoft Excel at Tech Republic. Or you can download an example workbook with the functions.

Note that these functions call a subroutine called QuickSort, which I copied from John Walkenbach‘s book Power Programming with Excel VBA years ago. (Highly recommended if you use Excel a lot and want to learn to automate repetitive tasks or do more advanced stuff.)

Function MyLarge(x, k)
'Replicates Excel's LARGE function, but will not balk at errors
'Returns the k-th largest value in a data set.
'Usage: =MYLARGE(A1:A15,3), returns the third largest value in the range A1 to A15

Dim arr() As Double 'An array to hold the cell values
Dim i As Long  'counter for looping through the array
Dim n As Long  'n is the number of elements in array
Dim nrev As Long  'revised count of number of VALID elements in array x

nrev = -1
n = Int(x.Count)
ReDim arr(n) As Double

'Note that Excel ranges always start with an index = 1
For i = 1 To n
  If Not IsEmpty(x(i)) And Not IsError(x(i)) And IsNumeric(x(i)) Then
    nrev = nrev + 1
    arr(nrev) = x(i)
  End If
Next i

ReDim Preserve arr(nrev)
Call Quicksort(arr, 0, nrev)

On Error GoTo IndexError
  MyLarge = arr(nrev - k + 1)
  Exit Function

IndexError:
  MyLarge = CVErr(xlErrNum)

End Function

Function MySmall(x, k)
'Replicates Excel's SMALL function, but will not balk at errors
'Returns the k-th smallest value in a data set.
'Usage: =MYSMALL(A1:A15,3), returns the third smallest value in the range A1 to A15

Dim arr() As Double 'An array to hold the cell values
Dim i As Long  'counter for looping through the array
Dim n As Long  'n is the number of elements in array
Dim nrev As Long  'revised count of number of VALID elements in array x

nrev = -1
n = Int(x.Count)
ReDim arr(n) As Double

'Note that Excel ranges always start with an index = 1
For i = 1 To n
  If Not IsEmpty(x(i)) And Not IsError(x(i)) And IsNumeric(x(i)) Then
    nrev = nrev + 1
    arr(nrev) = x(i)
  End If
Next i

ReDim Preserve arr(nrev)
Call Quicksort(arr, 0, nrev)

On Error GoTo IndexError
  MySmall = arr(k - 1)
  Exit Function

IndexError:
  MySmall = CVErr(xlErrNum)

End Function

Sub Quicksort(values() As Double, ByVal min As Long, ByVal max As Long)

'A fairly efficient sort algorithm for sorting 1-dimensional arrays of numbers
'Source: Walkenbach, J., 1999, Power Programming for Excel/VBA

'values() is the 1-dimensional array to be sorted

'min is the array index for the beginning of slice of the array where the sort is to begin
'To sort the entire array, min = 0 or 1 (depending on what Base you are working in)

'max is the array index for the end of the part of the array to be sorted.
'To sort the entire array, use max = len(values)

'Note that this is an example of a *recursive algorithm*
'To understand recursive algorithms, first you have to understand recursive algorithms  

Dim med_value As String
Dim Hi As Long
Dim lo As Long
Dim i As Long

  ' If the list has only 1 item, it's sorted.
  If min >= max Then Exit Sub

  ' Pick a dividing item randomly.
  i = min + Int(Rnd(max - min + 1))
  med_value = values(i)

  ' Swap the dividing item to the front of the list.
  values(i) = values(min)

  ' Separate the list into sublists.
  lo = min
  Hi = max
  Do
    ' Look down from hi for a value < med_value.     Do While values(Hi) >= med_value
      Hi = Hi - 1
      If Hi <= lo Then Exit Do
    Loop

    If Hi <= lo Then       ' The list is separated.       values(lo) = med_value       Exit Do     End If     ' Swap the lo and hi values.     values(lo) = values(Hi)     ' Look up from lo for a value >= med_value.
    lo = lo + 1
    Do While values(lo) < med_value       lo = lo + 1       If lo >= Hi Then Exit Do
    Loop

    If lo >= Hi Then
      ' The list is separated.
      lo = Hi
      values(Hi) = med_value
      Exit Do
    End If

    ' Swap the lo and hi values.
    values(Hi) = values(lo)
  Loop ' Loop until the list is separated.

  ' Recursively sort the sublists.
  Quicksort values, min, lo - 1
  Quicksort values, lo + 1, max

End Sub